Dont tie derivation to python version 3.11

Author: jchbdemant

default.nix

@@ -3,41 +3,4 @@
     sha256 = "1lr1h35prqkd1mkmzriwlpvxcb34kmhc9dnr48gkm8hh089hifmx";
   }) {} ) }:
 
-let
-  pyproject = builtins.fromTOML (builtins.readFile ./pyproject.toml);
-  project = pyproject.project;
-in
-pkgs.python311Packages.buildPythonPackage rec {
-  pname = project.name;
-  inherit (project) version;
-
-  src = ./.;
-
-  format = "pyproject";
-
-  nativeCheckInputs = with pkgs.python311Packages; [
-    setuptools
-
-    pytest
-    pytest-cov
-
-    pkgs.git
-  ];
-
-  propagatedBuildInputs = with pkgs.python311Packages; [
-    pkgs.git
-    maya
-    colorama
-    dateparser
-  ];
-
-  checkPhase = ''
-     runHook preCheck
-     pytest
-     runHook postCheck
-  '';
-
-  postInstall = ''
-    install -Dm755 ${./aux/git_add_ssh_remote.sh} $out/bin/git_add_ssh_remote.sh
-  '';
-}
+pkgs.python3Packages.callPackage ./derivation.nix {}

derivation.nix

@@ -0,0 +1,48 @@
+{
+  buildPythonPackage,
+  setuptools,
+  pytest,
+  pytest-cov,
+  git,
+  maya,
+  colorama,
+  dateparser
+}:
+let
+  pyproject = builtins.fromTOML (builtins.readFile ./pyproject.toml);
+  project = pyproject.project;
+in
+buildPythonPackage rec {
+  pname = project.name;
+  inherit (project) version;
+
+  src = ./.;
+
+  format = "pyproject";
+
+  nativeCheckInputs = [
+    setuptools
+
+    pytest
+    pytest-cov
+
+    git
+  ];
+
+  propagatedBuildInputs = [
+    git
+    maya
+    colorama
+    dateparser
+  ];
+
+  checkPhase = ''
+     runHook preCheck
+     pytest
+     runHook postCheck
+  '';
+
+  postInstall = ''
+    install -Dm755 ${./aux/git_add_ssh_remote.sh} $out/bin/git_add_ssh_remote.sh
+  '';
+}