Idea - allow getaddrinfo to select the IP version property

[JPeterMugaas]

I noticed that some programs resolve localhost and my computer name to IPv6 addresses while resolving Internet hostnames to IPv4 addresses. Indy does not do this because it passes the IP version directly to the getaddrinfo through the hints property. I would like an option that allows getaddrinfo to return either an IPv4 or IPv6 depending upon the situation.

I wrote a function that does this but using it would probably an ugly workaround but I hope it is integrated into Indy somehow:

procedure ResolveHost(const AHostname : String;
  out VIPAddress : String;
  out VIPVersion : TIdIPVersion);
var
  {$IFDEF UNICODE}
  LAddrInfo: pAddrInfoW;
  Hints: TAddrInfoW;
  {$ELSE}
  LAddrInfo: pAddrInfo;
  Hints: TAddrInfo;
  {$ENDIF}
  RetVal: Integer;
  LHostName: String;
  {$IFDEF STRING_UNICODE_MISMATCH}
  LTemp: TIdPlatformString;
  {$ENDIF}
begin
  ZeroMemory(@Hints, SizeOf(Hints));
  Hints.ai_family := AF_UNSPEC;
  Hints.ai_socktype := SOCK_STREAM;
  LAddrInfo := nil;

  if UseIDNAPI then begin
    LHostName := IDNToPunnyCode(
      {$IFDEF STRING_IS_UNICODE}
      AHostName
      {$ELSE}
      TIdUnicodeString(AHostName) // explicit convert to Unicode
      {$ENDIF}
    );
  end else begin
    LHostName := AHostname;
  end;

  {$IFDEF STRING_UNICODE_MISMATCH}
  LTemp := TIdPlatformString(LHostName); // explicit convert to Ansi/Unicode
  {$ENDIF}
  if Assigned(getaddrinfo) then
  begin
    RetVal := getaddrinfo(
      {$IFDEF STRING_UNICODE_MISMATCH}PIdPlatformChar(LTemp){$ELSE}PChar(LHostName){$ENDIF},
      nil, @Hints, @LAddrInfo);
    if RetVal <> 0 then begin
      RaiseSocketError(gaiErrorToWsaError(RetVal));
    end;
  end;

  try
    if not Assigned(LAddrInfo) then
    begin
      case LAddrInfo^.ai_family of
      AF_INET :
        begin
          VIPVersion := Id_IPv4;
          VIPAddress := TranslateTInAddrToString(PSockAddrIn(LAddrInfo^.ai_addr)^.sin_addr, Id_IPv4);
        end;
        AF_INET6 :
        begin
          VIPVersion := Id_IPv6;
          VIPAddress := TranslateTInAddrToString(PSockAddrIn6(LAddrInfo^.ai_addr)^.sin6_addr, Id_IPv6);
        end;
      end;
    end;
  finally
    freeaddrinfo(LAddrInfo);
  end;
end;

[rlebeau]

Unfortunately, it is not as simple as just changing the behavior of ResolveHost(). When making an outgoing connection, Indy first creates the client socket and binds it locally using the specified IPVersion before it then resolves the Host using the same IPVersion. It would take a rewrite of Indy clients to resolve the Host first and then create+bind the socket using the resolved IPVersion. This is already addressed in #164.

To make this kind of code useful in the current codebase, users would have to manually call it before they call the client's Connect() method, setting the client's Host and IPVersion to the resolved IP rather than a hostname. And, this doesn't address the possibility that a hostname could resolve to both IPv4 and IPv6 at the same time, or that a hostname can resolve to multiple IPs that are not all reachable from the calling machine. So, the caller would have to be prepared to call Connect() multiple times with different Host+IPVersion combinations until one of them succeeds. #164 is meant to internalize that kind of logic.

---

On a side note, there is a bug in your code suggestion. if not Assigned(LAddrInfo) needs to be if Assigned(LAddrInfo) instead, or simply omitted completely since LAddrInfo would never be nil if getaddrinfo() is successful.