ADVobfuscator/CMakeLists.txt at main · andrivet/ADVobfuscator · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
cmake_minimum_required(VERSION 3.14)
project(advobfuscator VERSION 2.1.0 LANGUAGES CXX)

option(BUILD_TESTING "Build unit tests" ON)
option(BUILD_EXAMPLES "Build examples" ON)

set(CMAKE_CXX_STANDARD 20)
set(CMAKE_CXX_STANDARD_REQUIRED ON)

add_library(advobfuscator INTERFACE)

target_include_directories(advobfuscator INTERFACE
    $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include>
    $<INSTALL_INTERFACE:include>
)

include(GNUInstallDirs)
install(DIRECTORY include/ DESTINATION ${CMAKE_INSTALL_INCLUDEDIR})
install(TARGETS advobfuscator EXPORT advobfuscatorTargets)
install(EXPORT advobfuscatorTargets
        FILE advobfuscatorTargets.cmake
        NAMESPACE advobfuscator::
        DESTINATION ${CMAKE_INSTALL_DATADIR}/advobfuscator
)

include(CMakePackageConfigHelpers)
write_basic_package_version_file(
        "${CMAKE_CURRENT_BINARY_DIR}/advobfuscatorConfigVersion.cmake"
        VERSION ${PROJECT_VERSION}
        COMPATIBILITY SameMajorVersion
        ARCH_INDEPENDENT
)
configure_package_config_file(
        "${CMAKE_CURRENT_SOURCE_DIR}/cmake/AdvobfuscatorConfig.cmake.in"
        "${CMAKE_CURRENT_BINARY_DIR}/advobfuscatorConfig.cmake"
        INSTALL_DESTINATION ${CMAKE_INSTALL_DATADIR}/advobfuscator
)
install(FILES
        "${CMAKE_CURRENT_BINARY_DIR}/advobfuscatorConfig.cmake"
        "${CMAKE_CURRENT_BINARY_DIR}/advobfuscatorConfigVersion.cmake"
        DESTINATION ${CMAKE_INSTALL_DATADIR}/advobfuscator
)

if(BUILD_TESTING)
    enable_testing()
    add_subdirectory(tests)
endif()

if(BUILD_EXAMPLES)
    add_subdirectory(Examples)
endif()