Showing current directory as initial input when enabling preview with find-file

[jeffy1009]

Hi,

I experience that when enabling preview for find-file as directed in https://github.com/minad/consult/wiki#previewing-files-in-find-file, I don't get the initial input as in find-file.

I have enabled it by fixing :initial to default-directory as follows:

(defun consult-find-file-with-preview (prompt &optional dir default mustmatch initial pred)
  (interactive)
  (let ((default-directory (or dir default-directory))
        (minibuffer-completing-file-name t))
    (consult--read #'read-file-name-internal :state (consult--file-preview)
                   :prompt prompt
                   :initial default-directory
                   :require-match mustmatch
                   :predicate pred)))

I'm not sure it is the proper fix.

If it is, might as well worth fixing it in the wiki page.

[minad]

If it is, might as well worth fixing it in the wiki page.

If you think so, feel free to change the wiki.

[jeffy1009]

I tried but changing wiki page is blocked in my company :(
I'll close this anyways.

[jeffy1009]

The above only fills in the directory part.
The original find-file with ffap fills in the filename also. This is really convenient because C-x C-f RET on a file path will get me right to the file.

I've copied bulk of code from read-file-name-default to accomplish this.
It would better if there's simpler way to achieve this though.

  ;; Previewing files in find-file. https://github.com/minad/consult/wiki#previewing-files-in-find-file
  ;; Code partially copied from read-file-name-default
  (defun consult-find-file-with-preview (prompt &optional dir default-filename mustmatch initial pred)
    (interactive)
    (unless dir (setq dir (or default-directory "~/")))
    (unless (file-name-absolute-p dir) (setq dir (expand-file-name dir)))
    (unless default-filename
      (setq default-filename
            (cond
             ((null initial) buffer-file-name)
             ;; Special-case "" because (expand-file-name "" "/tmp/") returns
             ;; "/tmp" rather than "/tmp/" (bug#39057).
             ((equal "" initial) dir)
             (t (expand-file-name initial dir)))))
    ;; If dir starts with user's homedir, change that to ~.
    (setq dir (abbreviate-file-name dir))
    ;; Likewise for default-filename.
    (if default-filename
	(setq default-filename
	      (if (consp default-filename)
		  (mapcar 'abbreviate-file-name default-filename)
		(abbreviate-file-name default-filename))))
    (let ((insdef (cond
                   ((and insert-default-directory (stringp dir))
                    (if initial
			(cons (minibuffer-maybe-quote-filename (concat dir initial))
                              (length (minibuffer-maybe-quote-filename dir)))
                      (minibuffer-maybe-quote-filename dir)))
                   (initial (cons (minibuffer-maybe-quote-filename initial) 0))))
	  (minibuffer-completing-file-name t))
      (consult--read #'read-file-name-internal :state (consult--file-preview)
                     :prompt prompt
                     :initial insdef
                     :require-match mustmatch
                     :predicate pred
		     :default default-filename)))
  (setq read-file-name-function #'consult-find-file-with-preview)