sqlite3.m4: Fix cross compilation

sqlite3 version check uses AC_RUN_IFELSE without a cross compilation
argument, which makes cross builds from source fail.

Thanks to Helmut Grohne for the bug report on the Debian Bug Tracking
System (bug 1119126).

We now just use the upstream sqlite.m4 version from rra-c-util which
calls pkg-config if available or the AC_SEARCH_LIBS macro if not.

Author: Julien-Elie

m4/sqlite3.m4

@@ -46,31 +46,28 @@ dnl Restore CPPFLAGS, LDFLAGS, and LIBS to their previous values before
 dnl INN_LIB_SQLITE3_SWITCH was called.
 AC_DEFUN([INN_LIB_SQLITE3_RESTORE], [INN_LIB_HELPER_RESTORE([SQLITE3])])
 
-dnl Ensures SQLite v3 meets our minimum version requirement.
-AC_DEFUN([_INN_LIB_SQLITE3_SOURCE], [[
-#include <sqlite3.h>
-
-int main(void) {
-    return sqlite3_libversion_number() < 3008002;
-}
-]])
-
-dnl Checks if SQLite v3 is present.  The single argument, if "true", says to
-dnl fail if the SQLite library could not be found.
+dnl Checks if SQLite v3 is present. The single argument, if "true", says to
+dnl fail if the SQLite library could not be found. Prefer probing with
+dnl pkg-config if available and the --with flags were not given.
 AC_DEFUN([_INN_LIB_SQLITE3_INTERNAL],
-[AC_CACHE_CHECK([for a sufficiently recent SQLite],
-    [inn_cv_have_sqlite3],
-    [INN_LIB_HELPER_PATHS([SQLITE3])
-     INN_LIB_SQLITE3_SWITCH
-     LIBS="-lsqlite3 $LIBS"
-     AC_RUN_IFELSE([AC_LANG_SOURCE([_INN_LIB_SQLITE3_SOURCE])],
-        [inn_cv_have_sqlite3=yes],
-        [inn_cv_have_sqlite3=no])
+[INN_LIB_HELPER_PATHS([SQLITE3])
+ AS_IF([test x"$SQLITE3_CPPFLAGS" = x && test x"$SQLITE3_LDFLAGS" = x],
+    [PKG_PROG_PKG_CONFIG([], [PKG_CONFIG=false])
+     AS_IF([test x"$PKG_CONFIG" = x], [PKG_CONFIG=false])
+     PKG_CHECK_EXISTS([sqlite3],
+        [PKG_CHECK_MODULES([SQLITE3], [sqlite3])
+         SQLITE3_CPPFLAGS="$SQLITE3_CFLAGS"])])
+ AS_IF([test x"$SQLITE3_LIBS" = x],
+    [INN_LIB_SQLITE3_SWITCH
+     LIBS=
+     AC_SEARCH_LIBS([sqlite3_open_v2], [sqlite3],
+        [SQLITE3_LIBS="$LIBS"],
+        [AS_IF([test x"$1" = xtrue],
+            [AC_MSG_ERROR([cannot find usable libsqlite3 library])])])
      INN_LIB_SQLITE3_RESTORE])
- AS_IF([test x"$inn_cv_have_sqlite3" = xyes],
-    [SQLITE3_LIBS="-lsqlite3"],
-    [AS_IF([test x"$1" = xtrue],
-        [AC_MSG_ERROR([cannot find usable SQLite v3 library])])])])
+ INN_LIB_SQLITE3_SWITCH
+ AC_CHECK_HEADERS([sqlite3.h])
+ INN_LIB_SQLITE3_RESTORE])
 
 dnl The main macro for packages with mandatory SQLite v3 support.
 AC_DEFUN([INN_LIB_SQLITE3],

support/getrra-c-util

@@ -60,36 +60,6 @@ download() {
                     -e '/test x"$CLANG" = xyes/,+1d' \
                     ${TEMP}
                 sed -i -e '$d' ${TEMP}
-            elif [ "$3" = "sqlite3.m4" ]; then
-                sed -i -e '49 i \
-dnl Ensures SQLite v3 meets our minimum version requirement.\
-AC_DEFUN([_INN_LIB_SQLITE3_SOURCE], [[\
-#include <sqlite3.h>\
-\
-int main(void) {\
-    return sqlite3_libversion_number() < 3008002;\
-}\
-]])\
-\
-dnl Checks if SQLite v3 is present.  The single argument, if "true", says to\
-dnl fail if the SQLite library could not be found.\
-AC_DEFUN([_INN_LIB_SQLITE3_INTERNAL],\
-[AC_CACHE_CHECK([for a sufficiently recent SQLite],\
-    [inn_cv_have_sqlite3],\
-    [INN_LIB_HELPER_PATHS([SQLITE3])\
-     INN_LIB_SQLITE3_SWITCH\
-     LIBS="-lsqlite3 $LIBS"\
-     AC_RUN_IFELSE([AC_LANG_SOURCE([_INN_LIB_SQLITE3_SOURCE])],\
-        [inn_cv_have_sqlite3=yes],\
-        [inn_cv_have_sqlite3=no])\
-     INN_LIB_SQLITE3_RESTORE])\
- AS_IF([test x"$inn_cv_have_sqlite3" = xyes],\
-    [SQLITE3_LIBS="-lsqlite3"],\
-    [AS_IF([test x"$1" = xtrue],\
-        [AC_MSG_ERROR([cannot find usable SQLite v3 library])])])])\
-' \
-                    -e '49,71d' \
-                    ${TEMP}
             fi
         elif [ "$2" = "include/inn" ] || [ "$2" = "include/portable" ] \
             || [ "$2" = "include" ] || [ "$2" = "lib" ] || [ "$2" = "tests/lib" ] \